FIND


Returns the position of a string of text within another string.

Syntax:

FIND(findtext, texttosearch, startposition)
returns the character position of the first occurrence of findtext within texttosearch.
startposition (optional) is the position from which the search starts.
The search is case-sensitive. For case-insensitive search, see SEARCH().
The search will not use regular expressions. For searching with regular expressions, see SEARCH().
A failed search gives the #VALUE! error.

Example:

FIND("yo", "Yoyo")
returns 3. The search is case-sensitive.
FIND("cho", "choochoo"; 2)
returns 5.
FIND("xyz", "abcdef", 1)
returns #VALUE!.
NOTE: This is an error condition, which must be 'handled' if used as the argument to another function.
IF( FIND("xyz", "abcdef", 1) , "Substring Present", "ERR: Missing Substring" )
returns #VALUE! which is not very useful, therefore we could use either ISERROR() or ISNUMBER() for example:
IF( ISERROR( FIND("xyz", "abcdef", 1) ) , "ERR: Missing Substring", "Substring Present" ).
returns "ERR: Missing Substring" ... allowing the IF() to function, and not propagating the error from the FIND() function.
IF( ISNUMBER( FIND("xyz", "abcdef", 1) ) , "Substring Present", "ERR: Missing Substring" ).
returns "ERR: Missing Substring" ... allowing the IF() to function, and not propagating the error from the FIND() function.

NOTE: In practice, it may be more maintainable to use ISNUMBER() to avoid negative logic, and it is more indicative of the evaluation desired: if the substring has a position, then ISNUMBER() is TRUE, else ISNUMBER() is FALSE.






 
Created with Zapof